idea java 数据库生成entity idea连接数据库生成实体类

目录

• IDEA连接数据库
• 选择表生成实体
• 自定义配置

照旧，先说点废话，因为以前太蠢了，每次数据库里的表的字段要去生成实体对象时，都哼哧哼哧自己手动去写那些该死的字段名，还有可能手写写错，如今我终于悟了，一定有其他人也不想做这件事，代码就是用来偷懒的

果然IDEA深得我心，可以在连接数据库之后生成实体类，非常之好用，甚至还可以支持你自定义去转换类型和加一些注解

但是推荐写一个空的项目去生成这样的实体类，然后再复制到自己的真实项目中

好的，废话完毕！ 正文开始

IDEA连接数据库

IDEA右边侧栏有个DataSource，可以通过这个来连接数据库，我们先成功连接数据库

点击进入后填写数据库进行连接，注意记得一定要去Test Connection 确保正常连接

选择表生成实体

选择一个表右键，选择如下选项进行生成，会弹出一个选择存放实体类路径的窗口，选择放在合适的目录下就好

自定义配置

如果发现数据库的某些字段没有转换成你需要的字段，如varbinary会自动转换成String，但你想让其转换为byte或其他类型，可以更改groovy脚本，在project中的如下位置找到groovy脚本

可以在文件的这一部分更改映射关系

如果想在生成的字段上加一些注释，可以在groovy脚本中找到generate函数，然后在其输出这里进行更改，如我在这里增加了@TableField注解

比较完善的一个groovy脚本，可以直接粘贴内容替换原来的groovy脚本

import com.intellij.database.model.DasTable
import com.intellij.database.model.ObjectKind
import com.intellij.database.util.Case
import com.intellij.database.util.DasUtil
import java.io.*
import java.text.SimpleDateFormat

//自定义包名
packageName = ""
typeMapping = [
        //类型映射
        (~/(?i)tinyint|smallint|mediumint/)      : "Integer",
        (~/(?i)int/)                             : "Long",
        (~/(?i)bool|bit/)                        : "Boolean",
        (~/(?i)float|double|decimal|real/)       : "BigDecimal",
        (~/(?i)datetime|timestamp|date|time/)    : "Date",
        (~/(?i)blob|binary|bfile|clob|raw|image/): "InputStream",
        (~/(?i)/)                                : "String"
]


FILES.chooseDirectoryAndSave("Choose directory", "Choose where to store generated files") { dir ->
    SELECTION.filter { it instanceof DasTable && it.getKind() == ObjectKind.TABLE }.each { generate(it, dir) }
}


def generate(table, dir) {
    def className = javaName(table.getName(), true)
    def fields = calcFields(table)
    packageName = getPackageName(dir)
    PrintWriter printWriter = new PrintWriter(new OutputStreamWriter(new FileOutputStream(new File(dir, className + ".java")), "UTF-8"))
    printWriter.withPrintWriter {out -> generate(out, className, fields,table)}
}

def getPackageName(dir) {
    return dir.toString().replaceAll("\\\\", ".").replaceAll("/", ".").replaceAll("^.*src(\\.main\\.java\\.)?", "") + ";"
}

def generate(out, className, fields,table) {
    out.println "package $packageName"
    out.println ""
    out.println "import javax.persistence.Column;"
    out.println "import javax.persistence.Entity;"
    out.println "import javax.persistence.Table;"
    out.println "import java.io.Serializable;"
    out.println "import lombok.Data;"
    out.println("import javax.persistence.Id;")

    Set types = new HashSet()

    fields.each() {
        types.add(it.type)
    }

    if (types.contains("Date")) {
        out.println "import java.util.Date;"
    }

    if (types.contains("InputStream")) {
        out.println "import java.io.InputStream;"
    }
    out.println ""
    out.println "/**\n" +
            " * @Title "+ table.getName()+" \n" +
            " * @Description  \n" +
            " * @author liyuan \n" +
            " * @Date "+ new SimpleDateFormat("yyyy-MM-dd").format(new Date()) + " \n" +
            " */"
    out.println ""
    out.println "@Entity"
    out.println "@Table ( name =\""+table.getName() +"\" )"
    out.println "@Data"
    out.println "public class $className  implements Serializable {"
    out.println ""
    out.println genSerialID()
    fields.each() {
        out.println ""

        //添加字段注释
        if (isNotEmpty(it.commoent)) {
            out.println "\t/**"
            out.println "\t * ${it.commoent.toString()}"
            out.println "\t */"
        }

        //为字段添加注解
        if (it.annos != "") out.println "   ${it.annos.replace("[@Id]", "")}"

        //显示变量
        out.println "\tprivate ${it.type} ${it.name};"
    }

    out.println ""
    out.println "}"
}

def calcFields(table) {
    DasUtil.getColumns(table).reduce([]) { fields, col ->
        def spec = Case.LOWER.apply(col.getDataType().getSpecification())
        def typeStr = typeMapping.find { p, t -> p.matcher(spec).find() }.value
        def comm =[
                colName : col.getName(),
                name :  javaName(col.getName(), false),
                type : typeStr,
                commoent: col.getComment(),
                annos: "\t@Column(name = \""+col.getName()+"\")"]
        if("id".equals(Case.LOWER.apply(col.getName())))
            comm.annos +="\n\t@Id"
        fields += [comm]
    }
}

def javaClassName(str, capitalize) {
    def s = com.intellij.psi.codeStyle.NameUtil.splitNameIntoWords(str)
            .collect { Case.LOWER.apply(it).capitalize() }
            .join("")
            .replaceAll(/[^\p{javaJavaIdentifierPart}[_]]/, "_")
    s = s[1..s.size() - 1]
    capitalize || s.length() == 1? s : Case.LOWER.apply(s[0]) + s[1..-1]
}

def javaName(str, capitalize) {
    def s = com.intellij.psi.codeStyle.NameUtil.splitNameIntoWords(str)
            .collect { Case.LOWER.apply(it).capitalize() }
            .join("")
            .replaceAll(/[^\p{javaJavaIdentifierPart}[_]]/, "_")
    capitalize || s.length() == 1? s : Case.LOWER.apply(s[0]) + s[1..-1]
}

def isNotEmpty(content) {
    return content != null && content.toString().trim().length() > 0
}

static String changeStyle(String str, boolean toCamel){
    if(!str || str.size() <= 1)
        return str

    if(toCamel){
        String r = str.toLowerCase().split('_').collect{cc -> Case.LOWER.apply(cc).capitalize()}.join('')
        return r[0].toLowerCase() + r[1..-1]
    }else{
        str = str[0].toLowerCase() + str[1..-1]
        return str.collect{cc -> ((char)cc).isUpperCase() ? '_' + cc.toLowerCase() : cc}.join('')
    }
}

static String genSerialID()
{
    return "\tprivate static final long serialVersionUID =  "+Math.abs(new Random().nextLong())+"L;"
}

done! 又是学到了的一天