java 处理mqtt 遗嘱消息重复播报 mqtt 遗嘱机制

转载

编程思想者 2024-01-16 15:12:59

文章标签 物联网网络协议客户端服务器时间间隔 文章分类 Java 后端开发

文章目录

ESP8266 MQTT 遗嘱应用

1 MQTT遗嘱基本应用
2 利用MQTT遗嘱实现设备在线状态发布

ESP8266 MQTT 遗嘱应用

PubSubClient库
官网地址：https://pubsubclient.knolleary.net/
GitHub：https://github.com/knolleary/pubsubclient/
百度网盘下载： https://pan.baidu.com/s/12MHGbdfiOdwOGip5RMSSEQ 提取码: sizy

1 MQTT遗嘱基本应用

本示例程序将实现ESP8266的最基本MQTT遗嘱应用。程序使用connect函数对遗嘱消息实现设置。

/**********************************************************************
项目名称/Project          : 零基础入门学用物联网
程序名称/Program name     : last_will_no_retain
团队/Team                : 太极创客团队 / Taichi-Maker (www.taichi-maker.com)
作者/Author              : CYNO朔
日期/Date（YYYYMMDD）     : 20201223
程序目的/Purpose          : 
本程序旨在演示如何设置客户端遗嘱机制。客户端在连接服务器时，设置遗嘱的主题和信息。
 
MQTT服务器会定时检查客户端是否仍然与服务器连接。为了实现这一检查，服务器将会根据以下
内容进行检查.
1. 客户端连接时会提供心跳时间间隔（Keep Alive）。
2. 如果在心跳时间间隔时长内，客户端向服务器发布了消息，则
   服务器会认为客户端与服务器保持连接无误。
3. 如果在心跳时间间隔时长内，客户端没有向服务端发布消息，
   客户端会向服务端发送pingreq信息。此信息由PubSubClient库自动发送。
4. 我们可以通过setKeepAlive函数控制心跳时间间隔时长，或者可以通过PubSubClient.h
   的#define MQTT_KEEPALIVE 15来设置心跳时间间隔时长。
4. 在心跳时间间隔的1.5倍时长内，如果服务端没有收到客户端信息也没有pingreq。
   那么服务端将会执行客户端遗嘱机制。
 
默认情况下，设备的心跳时间间隔时长为15秒。这是在PubSubClient.h中通过以下语句定义的：
#define MQTT_KEEPALIVE 15
 
若要修改keep-alive时间，可修改以上头文件，或者使用setKeepAlive函数实现。
 
对于PubSubClient,遗嘱QoS允许使用0，1。
-----------------------------------------------------------------------
本示例程序为太极创客团队制作的《零基础入门学用物联网》中示例程序。
该教程为对物联网开发感兴趣的朋友所设计和制作。如需了解更多该教程的信息，请参考以下网页：
http://www.taichi-maker.com/homepage/esp8266-nodemcu-iot/iot-c/esp8266-nodemcu-web-client/http-request/
***********************************************************************/
#include <ESP8266WiFi.h>
#include <PubSubClient.h>
 
// 设置wifi接入信息(请根据您的WiFi信息进行修改)
const char* ssid = "taichi-maker";
const char* password = "12345678";
const char* mqttServer = "test.ranye-iot.net";
// 如以上MQTT服务器无法正常连接，请前往以下页面寻找解决方案
// http://www.taichi-maker.com/public-mqtt-broker/
 
WiFiClient wifiClient;
PubSubClient mqttClient(wifiClient);
 
// 遗嘱设置
const char* willMsg = "CLIENT-OFFLINE"; // 遗嘱消息内容
const int willQoS = 0;                   // 遗嘱QoS
const bool willRetain = false;           // 遗嘱保留
 
void setup() {
  Serial.begin(9600);               // 启动串口通讯
  
  //设置ESP8266工作模式为无线终端模式
  WiFi.mode(WIFI_STA);
  
  // 连接WiFi
  connectWifi();
  
  // 设置MQTT服务器和端口号
  mqttClient.setServer(mqttServer, 1883);
  mqttClient.setKeepAlive(10); // 设置心跳间隔时间
  
  // 连接MQTT服务器
  connectMQTTserver();
}
 
void loop() {
  // 如果开发板未能成功连接服务器，则尝试连接服务器
  if (!mqttClient.connected()) {
    connectMQTTserver();
  }
 
   // 处理信息以及心跳
   mqttClient.loop();
}
 
// 连接MQTT服务器并订阅信息
void connectMQTTserver(){
  
  // 根据ESP8266的MAC地址生成客户端ID（避免与其它ESP8266的客户端ID重名）
  String clientId = "esp8266-" + WiFi.macAddress();
 
  // 建立遗嘱主题。主题名称以Taichi-Maker-为前缀，后面添加设备的MAC地址，最后
  // 以“-Will”结尾，这是为确保不同ESP8266客户端的遗嘱主题名称各不相同。
  String willString = "Taichi-Maker-" + WiFi.macAddress() + "-Will";
  char willTopic[willString.length() + 1];  
  strcpy(willTopic, willString.c_str());
 
  // 连接MQTT服务器，在连接过程中提供以下参数：
  // 客户端ID，遗嘱主题，遗嘱QoS，遗嘱保留，遗嘱信息
  if (mqttClient.connect(clientId.c_str(), willTopic, willQoS, willRetain, willMsg)){ 
    Serial.println("MQTT Server Connected.");
    Serial.print("Server Address: ");Serial.println(mqttServer);
    Serial.print("ClientId: ");Serial.println(clientId);
    Serial.print("Will Topic: ");Serial.println(willTopic);    
  } else {
    Serial.print("MQTT Server Connect Failed. Client State:");
    Serial.println(mqttClient.state());
    delay(5000);
  }   
}
 
// ESP8266连接wifi
void connectWifi(){
 
  WiFi.begin(ssid, password);
 
  //等待WiFi连接,成功连接后输出成功信息
  while (WiFi.status() != WL_CONNECTED) {
    delay(1000);
    Serial.print(".");
  }
  Serial.println("");
  Serial.println("WiFi Connected!");  
  Serial.println(""); 
}

2 利用MQTT遗嘱实现设备在线状态发布

通过以下程序，ESP8266客户端可以利用遗嘱机制来实时的将当前在线与否状态通过服务端进行发布。也就是说，其它客户端只要订阅ESP8266客户端的遗嘱主题就可以马上了解该客户端是否在线。

/**********************************************************************
项目名称/Project          : 零基础入门学用物联网
程序名称/Program name     : last_will_retain
团队/Team                : 太极创客团队 / Taichi-Maker (www.taichi-maker.com)
作者/Author              : CYNO朔
日期/Date（YYYYMMDD）     : 20201223
程序目的/Purpose          : 
本程序旨在演示如何设置客户端遗嘱机制。客户端在连接服务器时，设置遗嘱的主题和信息。
本客户端所发布的遗嘱消息为保留消息。其它客户端可通过订阅本客户端的遗嘱主题获取本
客户端是否在线的状态信息。
-----------------------------------------------------------------------
本示例程序为太极创客团队制作的《零基础入门学用物联网》中示例程序。
该教程为对物联网开发感兴趣的朋友所设计和制作。如需了解更多该教程的信息，请参考以下网页：
http://www.taichi-maker.com/homepage/esp8266-nodemcu-iot/iot-c/esp8266-nodemcu-web-client/http-request/
***********************************************************************/
#include <ESP8266WiFi.h>
#include <PubSubClient.h>
 
// 设置wifi接入信息(请根据您的WiFi信息进行修改)
const char* ssid = "taichimaker";
const char* password = "12345678";
const char* mqttServer = "test.ranye-iot.net";
// 如以上MQTT服务器无法正常连接，请前往以下页面寻找解决方案
// http://www.taichi-maker.com/public-mqtt-broker/
 
WiFiClient wifiClient;
PubSubClient mqttClient(wifiClient);
 
// 遗嘱设置
const char* willMsg = "CLIENT-OFFLINE"; // 遗嘱消息内容
const int willQoS = 0;                   // 遗嘱QoS
const bool willRetain = true;           // 遗嘱保留
 
void setup() {
  Serial.begin(9600);               // 启动串口通讯
  
  //设置ESP8266工作模式为无线终端模式
  WiFi.mode(WIFI_STA);
  
  // 连接WiFi
  connectWifi();
  
  // 设置MQTT服务器和端口号
  mqttClient.setServer(mqttServer, 1883);
  mqttClient.setKeepAlive(10); // 设置心跳间隔时间
  
  // 连接MQTT服务器
  connectMQTTserver();
}
 
void loop() {
  // 如果开发板未能成功连接服务器，则尝试连接服务器
  if (!mqttClient.connected()) {
    connectMQTTserver();
  }
 
   // 处理信息以及心跳
   mqttClient.loop();
}
 
// 连接MQTT服务器并订阅信息
void connectMQTTserver(){
  
  // 根据ESP8266的MAC地址生成客户端ID（避免与其它ESP8266的客户端ID重名）
  String clientId = "esp8266-" + WiFi.macAddress();
 
  // 建立遗嘱主题。主题名称以Taichi-Maker-为前缀，后面添加设备的MAC地址，最后
  // 以“-Will”结尾，这是为确保不同ESP8266客户端的遗嘱主题名称各不相同。
  String willString = "Taichi-Maker-" + WiFi.macAddress() + "-Will";
  char willTopic[willString.length() + 1];  
  strcpy(willTopic, willString.c_str());
 
  // 连接MQTT服务器，在连接过程中提供以下参数：
  // 客户端ID，遗嘱主题，遗嘱QoS，遗嘱保留，遗嘱信息
  if (mqttClient.connect(clientId.c_str(), willTopic, willQoS, willRetain, willMsg)){ 
    Serial.println("MQTT Server Connected.");
    Serial.print("Server Address: ");Serial.println(mqttServer);
    Serial.print("ClientId: ");Serial.println(clientId);
    Serial.print("Will Topic: ");Serial.println(willTopic);    
    publishOnlineStatus();     //发布在线状态
  } else {
    Serial.print("MQTT Server Connect Failed. Client State:");
    Serial.println(mqttClient.state());
    delay(5000);
  }   
}
 
// 发布信息
void publishOnlineStatus(){
  // 建立遗嘱主题。主题名称以Taichi-Maker-为前缀，后面添加设备的MAC地址，最后
  // 以“-Will”结尾，这是为确保不同ESP8266客户端的遗嘱主题名称各不相同。
  String willString = "Taichi-Maker-" + WiFi.macAddress() + "-Will";
  char willTopic[willString.length() + 1];  
  strcpy(willTopic, willString.c_str());
 
  // 建立设备在线的消息。此信息将以保留形式向遗嘱主题发布
  String onlineMessageString = "CLIENT-ONLINE"; 
  char onlineMsg[onlineMessageString.length() + 1];   
  strcpy(onlineMsg, onlineMessageString.c_str());
  
  // 向遗嘱主题发布设备在线消息
  if(mqttClient.publish(willTopic, onlineMsg, true)){
    Serial.print("Published Online Message: ");Serial.println(onlineMsg);    
  } else {
    Serial.println("Online Message Publish Failed."); 
  }
}
 
// ESP8266连接wifi
void connectWifi(){
 
  WiFi.begin(ssid, password);
 
  //等待WiFi连接,成功连接后输出成功信息
  while (WiFi.status() != WL_CONNECTED) {
    delay(1000);
    Serial.print(".");
  }
  Serial.println("");
  Serial.println("WiFi Connected!");  
  Serial.println(""); 
}

详情可见太极创客官网，内有Arduino、ESP32等详细教程

本文章为转载内容，我们尊重原作者对文章享有的著作权。如有内容错误或侵权问题，欢迎原作者联系我们进行内容更正或删除文章。