最佳分配算法 PYTHON

转载

coolfengsy 2024-11-19 19:45:58

文章标签 最佳分配算法 PYTHON 最小值匈牙利算法 sed 文章分类 Python 后端开发

介绍

分配问题是基本的优化问题之一。简单来说，要问的问题是这样的：

有斧头工人数和y个工作。可以为任何工人分配任何工作，但是每个工人和工作的组合都具有相关的成本。应该以使分配的总成本最小化的方式分配所有工人的工作。

可以概括术语“工人，工作和成本”。他们不一定必须适合那种确切的情况。任何时候您需要以最佳方式将一件事分配给另一件事都被视为分配问题。例如，如果您需要根据他们最喜欢的时间段将学生分配给班级。在这种情况下，工人是学生，工作是班级，而时间段偏好是成本。 http://en.wikipedia.org/wiki/Assignment_problem 匈牙利算法

匈牙利算法解决了多项式时间内的分配问题。它由Harold Kuhn在1955年开发和出版。

通常，该算法通过获取二维成本矩阵并对其执行运算以创建零，直到可以分配所有内容为止。

这些步骤是：

从一行中取最低成本，然后从该行中的所有成本中减去。
从一列中获取最低成本，然后从该列中的所有成本中扣除。
在列或行中分配零，然后在该列和行中划掉其他零。继续直到不存在任何零。
如果一行或一列包含多个零（即，多个工作人员可以以相同的成本完成工作，或者一个工作人员可以以相同的成本进行多个工作），则应分配任何零，然后将其划掉。
返回第3步，继续直到所有零都被分配或删除。
如果每个工作都被分配，您就完成了。
使用可能的最少行覆盖矩阵中存在的所有零（有多种方法可以执行此操作）
从未发现的单元格中减去最小值，然后从所有未发现的单元格中减去最小值。将最小值添加到行和列都覆盖的那些单元格中。
返回步骤3。

http://en.wikipedia.org/wiki/Hungarian_algorithm 代码及其使用方法

下面的代码是VBScript中匈牙利算法的示例实现，可轻松移植到VBA。它使用具有以下测试数据的成本矩阵：

工作人员是行，工作是列，单元格值是将工作人员分配给该工作的成本。

该示例可以打包成一个函数，在其中提供成本矩阵并输出分配矩阵。

该实现方式还限于分配问题的线性形式。意味着有一对一的工作分配给工人。它可以处理一个是否多于一个。但是，不能将同一工人分配给多个工作，反之亦然。

如果需要，该算法应该能够通过对分配部分进行一些修改来适应该算法。我在考虑其他变量来跟踪每个工作的分配和每个工人的分配。

' costMatrix(x, y, z)
' x = worker
' y = job
' z = properties 
' properties
' 0 = cost
' 1 = is assigned
' 2 = is marked row
' 3 = is marked column
' 4 = is covered row
' 5 = is covered column 
Option Explicit 
Const workers = 3 ' 0 based
Const jobs = 3 ' 0 based 
Dim costMatrix
Dim jobAssignments
Dim wrkAssignments
Dim n, k, i, j
Dim minimum
Dim output
Dim assignedCount
Dim loopCount
Dim zeroIndex
Dim didAssign 
ReDim costMatrix(workers, jobs, 5)
ReDim jobAssignments(jobs)
ReDim wrkAssignments(workers) 
' Populate cost matrix
costMatrix(0, 0, 0) = 1
costMatrix(0, 1, 0) = 3
costMatrix(0, 2, 0) = 5
costMatrix(0, 3, 0) = 3
costMatrix(1, 0, 0) = 2
costMatrix(1, 1, 0) = 4
costMatrix(1, 2, 0) = 6
costMatrix(1, 3, 0) = 1
costMatrix(2, 0, 0) = 1
costMatrix(2, 1, 0) = 3
costMatrix(2, 2, 0) = 5
costMatrix(2, 3, 0) = 5
costMatrix(3, 0, 0) = 3
costMatrix(3, 1, 0) = 1
costMatrix(3, 2, 0) = 2
costMatrix(3, 3, 0) = 5 
' Step 1, subtract row min from rows
For i = 0 To workers
    minimum = 999999 
    ' Find minimum for the row
    For j = 0 To jobs
        If minimum > costMatrix(i, j, 0) Then
            minimum = costMatrix(i, j, 0)
        End If
    Next 
    ' Subtract minimum from each element in row
    For j = 0 To jobs
        costMatrix(i, j, 0) = costMatrix(i, j, 0) - minimum
    Next
Next 
' Step 2, subtract column min from columns
For j = 0 To jobs
    minimum = 999999 
    ' Find minimum for the column
    For i = 0 To workers
        If minimum > costMatrix(i, j, 0) Then
            minimum = costMatrix(i, j, 0)
        End If
    Next 
    ' Subtract minimum from each element in column
    For i = 0 To workers
        costMatrix(i, j, 0) = costMatrix(i, j, 0) - minimum
    Next
Next 
' Check and Loop Steps 3 and 4
loopCount = 0
Do
    loopCount = loopCount + 1 
    ' Reset assignments
    For i = 0 To workers
        wrkAssignments(i) = False
    Next 
    For j = 0 To jobs
        jobAssignments(j) = False
    Next 
    For i = 0 To workers
        For j = 0 To jobs
            costMatrix(i, j, 1) = 0
        Next
    Next 
    ' Assign workers
    Do
        didAssign = False 
        ' Assign lone 0's in rows
        For i = 0 To workers
            If wrkAssignments(i) = False Then
                assignedCount = 0 
                For j = 0 To jobs
                    If jobAssignments(j) = False And costMatrix(i, j, 0) = 0 Then
                        assignedCount = assignedCount + 1
                        zeroIndex = j
                    End If
                Next 
                If assignedCount = 1 Then
                    costMatrix(i, zeroIndex, 1) = 1
                    wrkAssignments(i) = True
                    jobAssignments(zeroIndex) = True
                    didAssign = True
                End If
            End If
        Next 
        If didAssign = False Then
            ' Assign lone 0's in columns
            For j = 0 To jobs
                If jobAssignments(j) = False Then
                    assignedCount = 0 
                    For i = 0 To workers
                        If wrkAssignments(i) = False And costMatrix(i, j, 0) = 0 Then
                            assignedCount = assignedCount + 1
                            zeroIndex = i
                        End If
                    Next 
                    If assignedCount = 1 Then
                        costMatrix(zeroIndex, j, 1) = 1
                        wrkAssignments(zeroIndex) = True
                        jobAssignments(j) = True
                        didAssign = True
                    End If
                End If
            Next
        End If 
        If didAssign = False Then
            ' Assign first 0
            For i = 0 To workers
                If wrkAssignments(i) = False Then
                    For j = 0 To jobs
                        If didAssign = False Then
                            If jobAssignments(j) = False And costMatrix(i, j, 0) = 0 Then
                                costMatrix(i, j, 1) = 1
                                wrkAssignments(i) = True
                                jobAssignments(j) = True
                                didAssign = True
                            End If
                        End If
                    Next
                End If
            Next
        End If 
        ' Exit loop if all 0's accounted for
        assignedCount = 0 
        For i = 0 To workers
            For j = 0 To jobs
                If wrkAssignments(i) = False And jobAssignments(j) = False And costMatrix(i, j, 0) = 0 Then
                    assignedCount = assignedCount + 1
                End If
            Next
        Next 
        If assignedCount = 0 Then
            Exit Do
        End If
    Loop 
    ' Check to see if all jobs have been assigned
    assignedCount = 0
    For j = 0 To jobs
        If jobAssignments(j) = True Then
            assignedCount = assignedCount + 1
        End If
    Next 
    If (assignedCount = (jobs + 1)) Or (assignedCount = (workers + 1)) Then
        ' Exit if every job has an assignment or every worker has an assignment
        Exit Do
    ElseIf loopCount > 100 Then
        ' Exit if looped too many times
        WScript.Echo "Too Many Loops"
        Exit Do
    End If 
    ' Prestep 3, unmark and uncover elements
    For i = 0 To workers
        For j = 0 To jobs
            costMatrix(i, j, 2) = 0
            costMatrix(i, j, 3) = 0
            costMatrix(i, j, 4) = 0
            costMatrix(i, j, 5) = 0
        Next
    Next 
    ' Step 3a, mark rows and columns
    For i = 0 To workers
        assignedCount = 0 
        ' Check to see if row (worker) has an assignment
        For j = 0 To jobs
            If costMatrix(i, j, 1) = 1 Then
                assignedCount = 1
            End If
        Next 
        If assignedCount = 0 Then
            ' No assignments so mark row
            For j = 0 To jobs
                costMatrix(i, j, 2) = 1 
                ' Mark column if cost is 0 in row
                If costMatrix(i, j, 0) = 0 Then
                    For n = 0 To workers
                        costMatrix(n, j, 3) = 1
                    Next
                End If
            Next
        End If
    Next 
    ' Check if column is marked
    For j = 0 To jobs
        If costMatrix(0, j, 3) = 1 Then
            ' Check if row is assigned in column
            For i = 0 To workers
                If costMatrix(i, j, 1) = 1 Then
                    ' Mark row if both true
                    For k = 0 To jobs
                        costMatrix(i, k, 2) = 1
                    Next
                End If
            Next
        End If
    Next 
    ' Step 3b, cover marked columns and unmarked rows
    For i = 0 To workers
        For j = 0 To jobs
            If costMatrix(i, j, 2) = 0 Then costMatrix(i, j, 4) = 1
            If costMatrix(i, j, 3) = 1 Then costMatrix(i, j, 5) = 1
        Next
    Next 
    ' Step 4, subtract minimum from uncovered cells, add minimum to double covered cells 
    ' Find minimum from uncovered cells
    minimum = 999999
    For i = 0 To workers
        For j = 0 To jobs
            If costMatrix(i, j, 4) = 0 And costMatrix(i, j, 5) = 0 Then
                If minimum > costMatrix(i, j, 0) Then
                    minimum = costMatrix(i, j, 0)
                End If
            End If
        Next
    Next 
    ' Subtract from uncovered, add to double covered 
    For i = 0 To workers
        For j = 0 To jobs
            If costMatrix(i, j, 4) = 0 And costMatrix(i, j, 5) = 0 Then
                costMatrix(i, j, 0) = costMatrix(i, j, 0) - minimum
            ElseIf costMatrix(i, j, 4) = 1 And costMatrix(i, j, 5) = 1 Then
                costMatrix(i, j, 0) = costMatrix(i, j, 0) + minimum
            End If
        Next
    Next
Loop 
output = ""
For i = 0 To workers
    For j = 0 To jobs
        output = output & costMatrix(i, j, 1) & " | "
    Next
    output = output & vbCrLf
Next 
WScript.Echo output

本文章为转载内容，我们尊重原作者对文章享有的著作权。如有内容错误或侵权问题，欢迎原作者联系我们进行内容更正或删除文章。