本文介绍 Microsoft Excel 中 TEXT
说明
TEXT 函数将数值转换为文本，并使您可以使用特殊格式字符串指定显示格式。 要以可读性更高的格式显示数字，或要将数字与文本或符号合并时，此函数非常有用。 例如，假设单元格 A1 中包含数字 23.5。 要将此数字的 格式设置为美元金额，您可以使用下列公式：
=TEXT(A1,"$0.00")
在本例中，Excel 会显示 $23.50。
您也可以使用功能区的“开始”选项卡上的“数字”组中的命令来设置数字的格式。 但是，只有整个单元格是数字格式才能使用这些命令。 如果您要设置数字格式并将其与其他文本合并，则 TEXT
=TEXT(A1,"$0.00") & " per hour"
Excel 会显示 $23.50 per hour。
语法
TEXT(value, format_text)
TEXT 函数语法具有下列参数：
- value
- format_text
有关数字格式的准则
- 显示小数位和有效位 若要为包含小数点的分数或数字设置格式，应在 format_text
占位符 | 说明 |
0（零） | 如果数字的位数少于格式中的零的个数，则会显示无效零。 例如，如果键入 8.9，但希望将其显示为 8.90，请使用格式 #.00。 |
# | 遵循与 0(零) 相同的规则。 但是，如果所键入数字的小数点任一侧的位数小于格式中 # 符号的个数，则 Excel 不会显示多余的零。 例如，如果自定义格式为 #.##，而在单元格中键入了 8.9，则会显示数字 8.9。 |
? | 遵循与 0(零) 相同的规则。 但 Excel 会为小数点任一侧的无效零添加空格，以便使列中的小数点对齐。 例如，自定义格式 0.0? 将列中数字 8.9 和 88.99 |
.（句点） | 在数字中显示小数点。 |
- 如果数字的小数点右侧的位数大于格式中的占位符数，则该数字的小数位数会舍入到与占位符数相同。 如果小数点左侧的位数大于格式中的占位符数，则会显示多出的位数。 如果格式仅在小数点的左侧包含数字记号 (#)，则小于 1 的数字都以小数点开头；例如 .47。
显示内容 | 显示为 | 使用此格式 |
1234.59 | 1234.6 | "####.#" |
8.9 | 8.900 | "#.000" |
0.631 | 0.6 | "0.#" |
12 | 12.0 | "#.0#" |
44.398 | 44.398 | "???.???" |
5.25 | 5 1/4 | "# ???/???" |
- 显示千位分隔符
,（逗点） | 在数字中显示千位分隔符。 如果格式包含两旁带有数字记号 (#) 或零的逗号，则 Excel 会用逗号分隔千位数。 跟随在数字占位符后面的逗号会以 1,000 为倍数缩放数字。 例如，如果 format_text 参数是"#,###.0,"，则 Excel 会将数字 12,200,000 显示为 12,200.0。 |
显示内容 | 显示为 | 使用此格式 |
12000 | 12,000 | "#,###" |
12000 | 12 | "#," |
12200000 | 12.2 | "0.0,," |
有关日期和时间格式的准则
- 显示日、月和年 若要将数字显示为日期格式（如日、月和年），请在 format_text
m | 将月显示为不带前导零的数字。 |
mm | 根据需要将月显示为带前导零的数字。 |
mmm | 将月显示为缩写形式（Jan 到 Dec）。 |
mmmm | 将月显示为完整名称（January 到 December）。 |
mmmmm | 将月显示为单个字母（J 到 D）。 |
d | 将日显示为不带前导零的数字。 |
dd | 根据需要将日显示为带前导零的数字。 |
ddd | 将日显示为缩写形式（Sun 到 Sat）。 |
dddd | 将日显示为完整名称（Sunday 到 Saturday）。 |
yy | 将年显示为两位数字。 |
yyyy | 将年显示为四位数字。 |
显示内容 | 显示为 | 使用此格式 |
Months | 1–12 | "m" |
Months | 01–12 | "mm" |
Months | Jan–Dec | "mmm" |
Months | January–December | "mmmm" |
Months | J–D | "mmmmm" |
Days | 1-31 | "d" |
Days | 01-31 | "dd" |
Days | Sun–Sat | "ddd" |
Days | Sunday–Saturday | "dddd" |
Years | 00-99 | "yy" |
Years | 1900-9999 | "yyyy" |
- 显示小时、分钟和秒 若要显示时间格式（如小时、分钟和秒），请在 format_text
h | 将小时显示为不带前导零的数字。 |
[h] | 以小时为单位显示经过的时间。如果使用了公式，该公式返回小时数超过 24 的时间，请使用类似于 [h]:mm:ss |
hh | 根据需要将小时显示为带前导零的数字。 如果格式中包含 AM 或 PM，则基于 12 小时制显示小时。 否则，基于 24 小时制显示小时。 |
m | 将分钟显示为不带前导零的数字。 注意 m 或 mm 代码必须紧跟在 h 或 hh 代码之后或紧跟在 ss |
[m] | 以分钟为单位显示经过的时间。如果所用的公式返回的分钟数超过 60，请使用类似于 [mm]:ss |
mm | 根据需要将分钟显示为带前导零的数字。 注意 m 或 mm 代码必须紧跟在 h 或 hh 代码之后或紧跟在 ss |
s | 将秒显示为不带前导零的数字。 |
[s] | 以秒为单位显示经过的时间。如果所用的公式返回的秒数超过 60，请使用类似于 [ss] |
ss | 根据需要将秒显示为带前导零的数字。如果要显示秒的小数部分，请使用类似于 h:mm:ss.00 |
AM/PM、am/pm、A/P、a/p | 基于 12 小时制显示小时。 Excel 会为从午夜到中午的时间显示 AM、am、A 或 a，而为从中午到午夜的时间显示 PM、pm、P 或 p。 |
显示内容 | 显示为 | 使用此格式 |
Hours | 0-23 | "h" |
Hours | 00-23 | "hh" |
Minutes | 0-59 | "m" |
Minutes | 00-59 | "mm" |
Seconds | 0-59 | "s" |
Seconds | 00-59 | "ss" |
时间 | 4 AM | "h AM/PM" |
时间 | 4:36 PM | "h:mm AM/PM" |
时间 | 4:36:03 P | "h:mm:ss A/P" |
时间 | 4:36:03.75 | "h:mm:ss.00" |
经过的时间（小时和分钟） | 1:02 | "[h]:mm" |
经过的时间（分钟和秒） | 62:16 | "[mm]:ss" |
经过的时间（秒和百分之一秒） | 3735.80 | "[ss].00" |
有关货币、百分比和科学记数法格式的准则
- 包含货币符号 要在数字前面加美元符号 ($)，在 format_text 参数的开头键入美元符号（例如 "$#,##0.00"）。 若要在数字格式中输入以下货币符号之一，请按 Num Lock 并使用数字键盘键入该符号的 ANSI 代码。
输入内容 | 使用此组合键 |
¢ | Alt+0162 |
£ | Alt+0163 |
¥ | Alt+0165 |
| Alt+0128 |
- 注意
- 显示百分比 若要将数字显示为百分比形式 （例如，将 .08 显示为 8% 或将 2.8 显示为 280%） ，请在 format_text 参数中包含百分比符号 (%)。
- 显示科学记数法 若要用科学记数法（指数）格式显示数字，请在 format_text
E（E-、E+、e-、e+） | 用科学记数法（指数）格式显示数字。 Excel 会在“E”或“e”的右侧显示与小数点移动的位数相对应的数字。 例如，如果 format_text 参数是 "0.00E+00"，Excel 会将数字 12,200,000 显示为 1.22E+07。 如果您将 format_text 参数更改为 "#0.0E+0"，则 Excel 会显示 12.2E+6。 |
有关包含文本和添加空格的准则
- 如果在 format_text
$ | 美元符号（人民币符号） |
+ | 加号 |
( | 左括号 |
: | 冒号 |
^ | 扬抑符（脱字符） |
' | 撇号 |
{ | 左大括号 |
< | 小于号 |
= | 等于号 |
- | 减号 |
/ | 斜杠符号 |
) | 右括号 |
! | 感叹号 |
& | 与号 |
~ | 波形符 |
} | 右大括号 |
> | 大于号 |
| 空格字符 |
- format_text参数不能包含星号 (*)。
- 使用 TEXT 函数将数值转换成格式化文本，并且不能再将结果作为数字来进行计算。 若要设置单元格的格式以使其值保持数字格式，右键单击次单元格，单击“设置单元格格式”，然后在“设置单元格格式”对话框上的“数字”选项卡中设置您想要的格式选项。 有关使用“设置单元格格式”对话框的详细信息，请单击对话框右上角的“帮助”按钮 (?)。
示例
复制下表中的示例数据，然后将其粘贴进新的 Excel 工作表的 A1 单元格中。要使公式显示结果，请选中它们，按 F2，然后按 Enter。如果需要，可调整列宽以查看所有数据。
销售人员 | 销售额 | 数据 |
Burke | $2,800 | 39300.63 |
Dykstra | 40% | |
公式 | 说明 | 结果 |
=A2&" sold "&TEXT(B2, "$0.00")&" worth of units." | 将单元格 A2、文本字符串 " sold"、单元格 B2（货币格式）以及文本字符串 " worth of units." 合并为一个短语。 | Burke sold $2800.00 worth of units. |
=A3&" had "&TEXT(B3, "0%")&" of the total sales." | 将单元格 A3、字符串 " sold"、单元格 B3（百分比格式）和文本字符串 " of the total sales." 合并为一个短语。 | Dykstra had 40% of the total sales. |
="Date: " & TEXT(C2, "yyyy-mm-dd") | 以 4 位年、2 位月和 2 位日格式显示单元格 C2 中的值。 | 日期：2007-08-06 |
="Date-time: " & TEXT(C2, "m/d/yyyy h:mm AM/PM") | 以短日期、12 小时制格式显示单元格 C2 中的值。 | 日期/时间：2007-8-6 下午 3:07 |
=TEXT(C2, "0.00E+00") | 以科学记数（指数）格式显示单元格 C2 中的值。 | 3.93E+04 |
=TEXT(C2, "$#,##0.00") | 以货币格式和千位分隔符显示单元格 C2 中的值。 | $39,300.63 |
