SQL server management studio 调试存储过程

概述

　　ORACLE 提供可以把 PL/SQL 程序存储在数据库中，并可以在任何地方来运行它。这样就叫存储过程或函数。过程和函数统称为 PL/SQL 子程序，他们是被命名的 PL/SQL 块，均存储在数据库中，并通过输入、输出参数或输入/输出参数与其调用者交换信息。 过程和函数的唯一区别是函数总向调用者返回数据，而过程则不返回数据。

一、存储函数

1.创建函数

内嵌函数

CREATE [OR REPLACE] FUNCTION function_name
[ (argment [ { IN | IN OUT }] Type,
argment [ { IN | OUT | IN OUT } ] Type ]
[ AUTHID DEFINER | CURRENT_USER ]
RETURN return_type
{ IS | AS }
<类型.变量的说明>
BEGIN
FUNCTION_body
EXCEPTION
其它语句
END;
说明:
1) OR REPLACE 为可选. 有了它, 可以或者创建一个新函数或者替换相同名字的函数, 而不会出现冲突
2) 函数名后面是一个可选的参数列表, 其中包含 IN, OUT 或 IN OUT 标记. 参数之间用逗号隔开. IN  参数
标记表示传递给函数的值在该函数执行中不改变; OUT  标记表示一个值在函数中进行计算并通过该参
数传递 给调用语句; IN OUT  标记表示传递给函数的值可以变化并传递给调用语句.  若省略标记,  则参数
隐含为 IN 。
　　IN——只能从中取值，OUT——只能给他赋值，IN OUT——混合型（既可取值，也可赋值）
3) 因为函数需要返回一个值, 所以 RETURN 
4） IS就是原来的DECLARE部分

　　　　简单无参函数：

CREATE OR REPLACE FUNCTION hello
RETURN VARCHAR2
IS
--函数使用过程中需要的变量/记录类型/游标等
BEGIN
       RETURN 'hello world!';
END;

DECLARE
  v_return VARCHAR2(64);
BEGIN
       v_return := hello();
       dbms_output.put_line(v_return);
END;

 　　　　 带参数的函数

CREATE OR REPLACE FUNCTION get_salary(dept_id employees.department_id%type,
                                      emp_count OUT NUMBER)
RETURN 
       NUMBER
IS
       v_num NUMBER;
BEGIN
       SELECT sum(salary),count(*) INTO v_num,emp_count 
       FROM employees 
       WHERE department_id = dept_id;
       RETURN v_num;
EXCEPTION
       WHEN NO_DATA_FOUND THEN
            dbms_output.put_line('数据不存在!');
       WHEN OTHERS THEN
            dbms_output.put_line('未知错误！');
END;

　　位置调用法：

DECLARE
  v_sum NUMBER;
  v_num NUMBER;
BEGIN
       --注意第二个为输出参数
       v_sum := get_salary(80,v_num);
       dbms_output.put_line('80号部门总人数为：'||v_num||',总工资为：'||v_sum);
END;

　　名称调用法：

　　　　argument => parameter [,…]

　　其中：argument 为形式参数，它 必须与函数定义时所声明的形式参数名称相同。Parameter 为实际参数。在这种格式中，形势参数与实际参数成对出现，相互间关系唯一确定，所以参数的顺序可以任意排列。

 

DECLARE
  v_sum NUMBER;
  v_num NUMBER;
BEGIN
       --注意第二个为输出参数
       v_sum := get_salary(emp_count => v_num,dept_id => 80);
       dbms_output.put_line('80号部门总人数为：'||v_num||',总工资为：'||v_sum);
END;

混合使用法与此类似，不再赘述

二、存储过程

　　存储过程是没有返回值的

　　语法：

CREATE [OR REPLACE] PROCEDURE Procedure_name
[ (argment [ { IN | IN OUT }] Type,
argment [ { IN | OUT | IN OUT } ] Type ]
[ AUTHID DEFINER | CURRENT_USER ]
{ IS | AS }
<类型.变量的说明>
BEGIN
<执行部分>
EXCEPTION
<可选的异常错误处理程序>
END;

示例：

--删除员工
CREATE OR REPLACE PROCEDURE del_emp(emp_id IN employees.employee_id%type)
IS
    NO_RESULT EXCEPTION;
BEGIN
      DELETE FROM employees WHERE employee_id = emp_id;
      IF SQL%NOTFOUND THEN
         RAISE NO_RESULT;
      END IF;
      dbms_output.put_line('删除'||emp_id||'完成！');
EXCEPTION
       WHEN NO_RESULT THEN
            dbms_output.put_line('查无此人，无法删除！');       
END;

　　　　简单调用（使用PLSQL调用）：

DECLARE
  
BEGIN
      del_emp(206);    
END;

控制台调用，请使用：

EXEC[UTE] Procedure_name( parameter1, parameter2…);

更多存储过程相关，参考上文链接

如何调试与调试中遇到的问题，参考：

　　　　　　

　　　　　　

三、触发器

触发器在数据库里以独立的对象存储，它与存储过程不同的是，存储过程通过其它程序来启动运行或直接启动运行，而 触发器是由一个事件来启动运行。 即触发器是当某个事件发生时自动地隐式运行。并且，触发器不能接收参数。所以 运行触发器就叫触发或点火（firing） ）。ORACLE 事件指的是对数据库的表进行的INSERT 、UPDATE 及 及 DELETE

1.触发器分类

　　　　   DML 触发器

　　　　　　ORACLE 可以在 DML 语句进行触发，可以在 DML 操作前或操作后进行触发，并且 可以对每个行或语句操作上进行触发。

　　　　替代触发器
　　　　　　由于在 ORACLE 里，不能直接对由两个以上的表建立的视图进行操作。所以给出了替代触发器。

　　　　系统触发器
　　　　　　它可以在 ORACLE 数据库系统的事件中进行触发，如 ORACLE 系统的启动与关闭等　　

2.触发器组成　　 

　　　　触发事件：即在何种情况下触发 TRIGGER; 例如：INSERT, UPDATE, DELETE。　　 

　　　　触发时间：即该 TRIGGER 是在触发事件发生之前（BEFORE）还是之后(AFTER)触发，也就是触发事件和

　　　　　　　　该 TRIGGER 的操作顺序。
　　　　 触发器本身：即该 TRIGGER 被触发之后的目的和意图，正是触发器本身要做的事情。 例如：PL/SQL 块。
　　　　触发频率：说明触发器内定义的动作被执行的次数。即 语句级(STATEMENT) 触发器和行级(ROW) 触发器。
　　　　　　　　语句级(STATEMENT)触发器：是指当某触发事件发生时，该触发器只执行一次；
　　　　　　　　行级(ROW)触发器：是指当某触发事件发生时，对受到该操作影响的每一行数据，触发器都单独执行一次

3.语法

CREATE [OR REPLACE] TRIGGER trigger_name
{BEFORE | AFTER }
{INSERT | DELETE | UPDATE [OF column [, column …]]}
ON [schema.] table_name 
[FOR EACH ROW ]
[WHEN condition]
trigger_body;

其中：
BEFORE 和 AFTER 指出触发器的触发时序分别为前触发和后触发方式，前触发是在执行触发事件之前触
发当前所创建的触发器，后触发是在执行触发事件之后触发当前所创建的触发器。
FOR EACH ROW 选项说明触发器为行触发器。 行触发器和语句触发器的区别表现在：行触发器要求当一
个 DML 语句操做影响数据库中的多行数据时，对于其中的每个数据行，只要它们符合触发约束条件，均激
活一次触发器；而语句触发器将整个语句操作作为触发事件，当它符合约束条件时，激活一次触发器。 当
省略 FOR EACH ROW  选项时，BEFORE 和 AFTER 触发器为 语句触发器，而 INSTEAD OF 触发器则为行触发
器。
WHEN 子句说明触发约束条件。Condition 为一个逻辑表达时，其中必须包含相关名称，而不能包含查
询语句，也不能调用 PL/SQL 函数。WHEN 子句指定的触发约束条件只能用在 BEFORE 和 AFTER 行触发器
中，不能用在 INSTEAD OF 行触发器和其它类型的触发器中。
当一个基表被修改( INSERT, UPDATE, DELETE)时要执行的存储过程，执行时根据其所依附的基表改动而自
动触发，因此与应用程序无关，用数据库触发器可以保证数据的一致性和完整性。
每张表最多可建立 12 种类型的触发器，它们是:
BEFORE INSERT
BEFORE INSERT FOR EACH ROW
AFTER INSERT
AFTER INSERT FOR EACH ROW
BEFORE UPDATE
BEFORE UPDATE FOR EACH ROW
AFTER UPDATE
AFTER UPDATE FOR EACH ROW
BEFORE DELETE
BEFORE DELETE FOR EACH ROW
AFTER DELETE
AFTER DELETE FOR EACH ROW

　　示例：

CREATE OR REPLACE TRIGGER emp_update_trigger
AFTER update on employees
FOR EACH ROW
BEGIN
    dbms_output.put_line('已更新employees表！');
END;

　　执行语句，自动触发：

UPDATE employees SET salary = 22000 WHERE employee_id = 194

已更新employees表！
 
1 row updated

触发器限制：

CREATE TRIGGER 语句文本的字符长度不能超过 32KB；
  触发器体内的 SELECT  语句只能为 SELECT … INTO … 结构，或者为定义游标所使用的 SELECT  语句。
  触发器中不能使用数据库事务控制语句 COMMIT; ROLLBACK, SVAEPOINT 语句；
  由触发器所调用的过程或函数也不能使用数据库事务控制语句；

　触发器使用新旧值的语法：

:NEW 修饰符访问操作完成后列的值
:OLD 修饰符访问操作完成前列的值

　　使用示例：

CREATE OR REPLACE TRIGGER emp_update_trigger
AFTER update on employees
FOR EACH ROW
BEGIN
    dbms_output.put_line('更新前salary：'||:old.salary||',更新后salary'||:new.salary);
END;

SQL> UPDATE employees SET salary = 10010 WHERE employee_id = 194;
 
更新前salary：10086,更新后salary10010