flash中，getChildByName的效率测试及原理推测

用actionscript 3开发的同学都知道，根据名称获取显示对象可以通过getChildByName函数，那么，这个系统函数效率怎么样呢？我们做一个测试

package { 
    import flash.display.DisplayObject; 
    import flash.display.Sprite; 
    import flash.events.MouseEvent; 
    import flash.utils.getTimer; 
 
    /** 
     * @author [e-mail] 
     */ 
    public class Main extends Sprite { 
 
        public function Main():void { 
            var sp:Sprite = new Sprite(); 
            sp.graphics.beginFill(0xff00ff); 
            sp.graphics.drawRect(0, 0, 400, 400); 
            sp.graphics.endFill(); 
            addChild(sp); 
            addEventListener(MouseEvent.CLICK, onClick); 
            createSps(100000); 
        } 
 
        private function createSps(num:int):void { 
            for (var i:int = 0; i < num; i++){ 
                var sp:Sprite = new Sprite(); 
                sp.name = "name" + i; 
                addChild(sp); 
            } 
        } 
 
        private function onClick(e:MouseEvent):void { 
            var time:int = getTimer(); 
            var test:DisplayObject = getChildByName("name10000"); 
            trace(getTimer() - time); 
        } 
    } 
} 

就是在场景中创建10万个对象，然后获取第1万个，在我的机器上执行时间为1毫秒

如果换成

var test:DisplayObject = getChildByName("name50000"); 

执行时间为3毫秒

如果换成

var test:DisplayObject = getChildByName("name90000"); 

执行时间为6毫秒

以上充分说明，getChildByName函数为遍历查找，效率本身并没有做什么优化

同样的代码换成

var test:DisplayObject = getChildAt(90000); 

执行时间为0，说明显示对象在系统内是以显示层数为序存在数组里面

经过这样的测试，我想大家应该知道怎么去合理使用以及自己实现优化的方式来获取对象了。